pkgname=tcp_wrappers
pkgver=7.6
pkgrel=2
pkgdesc="Monitors and Controls incoming TCP connections"
arch=('i686' 'x86_64')
url="ftp://ftp.porcupine.org/pub/security/index.html"
license=('custom')
groups=('base')
backup=('etc/hosts.allow' 'etc/hosts.deny')
depends=('bash' 'glibc')
source=("ftp://ftp.porcupine.org/pub/security/${pkgname}_$pkgver.tar.gz"
        'hosts.allow'
        'hosts.deny'
        'try-from.8'
        'safe_finger.8'
        'shared_lib_plus_plus-1.patch'
        '01_all_redhat-bug11881.patch'
        '02_all_redhat-bug17795.patch'
        '03_all_wildcard.patch'
        '04_all_fixgethostbyname.patch'
        '07_all_sig.patch'
        '08_all_strerror.patch'
        '09_all_gcc-3.4.patch'
        '10_all_more-headers.patch'
        'tcp-wrappers-7.6-ipv6-1.14.patch')
md5sums=('e6fa25f71226d090f34de3f6b122fb5a'
         '32cfeeed797161034f62bb45f3167baa'
         'a0ee30f6aeaca241c4d44f7c177eca6b'
         '4a8f40f9a69f0848df92b232072e8561'
         '1a6d7b11abb1fd69ace775d02a1c72cf'
         '99345104130b91cb151af9d87eee1449'
         'e7ac7ae271703eacf175d597d329e11a'
         '2790301fbf1b4711e75d5b799b6d4ac8'
         'd286da9fca993f8afa89631133312151'
         '97d4d81faaecf0958eeb52c45df71e34'
         '374b8179b8d5c71979008c6a775d658e'
         '801292cacf14a92e2784b925e72a1db1'
         '0978932f49aae33834a46e189ace7d77'
         '68b1c7f82fed60b446b00f6de27c3b9f'
         '9154c38e3fb69d12b5bfb2fc5284314f')

build() {
  cd $srcdir/${pkgname}_$pkgver

  # add gentoo / fedora / redhat patches
  patch -Np1 -i $srcdir/shared_lib_plus_plus-1.patch || return 1
  patch -Np1 -i $srcdir/01_all_redhat-bug11881.patch || return 1
  patch -Np0 -i $srcdir/02_all_redhat-bug17795.patch || return 1
  patch -Np0 -i $srcdir/03_all_wildcard.patch || return 1
  patch -Np1 -i $srcdir/04_all_fixgethostbyname.patch || return 1
  patch -Np1 -i $srcdir/07_all_sig.patch || return 1
  patch -Np1 -i $srcdir/09_all_gcc-3.4.patch || return 1
  patch -Np1 -i $srcdir/10_all_more-headers.patch || return 1
  patch -Np2 -i $srcdir/tcp-wrappers-7.6-ipv6-1.14.patch || return 1
  
  make REAL_DAEMON_DIR=/usr/sbin STYLE=-DSYS_ERRLIST_DEFINED linux || return 1
  
  # dumb makefile
  mkdir -p $pkgdir/usr/{include,lib,sbin} || return 1
  mkdir -p $pkgdir/usr/share/man/man{3,5,8} || return 1
}

package() {
  cd $srcdir/${pkgname}_$pkgver

  make DESTDIR=$pkgdir install || return 1
  
  install -D -m644 $srcdir/hosts.allow $pkgdir/etc/hosts.allow || return 1
  install -D -m644 $srcdir/hosts.deny $pkgdir/etc/hosts.deny || return 1
  
  # add manpage symlinks for hosts.deny and hosts.allow
  cd $pkgdir/usr/share/man/man5 || return 1
  ln -s hosts_access.5.gz hosts.allow.5.gz || return 1
  ln -s hosts_access.5.gz hosts.deny.5.gz || return 1
  
  # install license
  mkdir -p $pkgdir/usr/share/licenses/$pkgname || return 1
  install -m644 $srcdir/${pkgname}_$pkgver/DISCLAIMER $pkgdir/usr/share/licenses/$pkgname/license.txt || return 1
}

# vim:set ts=2 sw=2 et:
